Forms: FreeAndNil ó Release y la validación Assigned?

[jbautista]

Hola que tal, bueno tengo un problema al liberar Form creados en tiempo de ejecución, el siguiente codigo me funciona perfectamente:


{si el Form no esta creado se crea y se muestra, y si le vuelven a dar click al boton entonces solo lo muestra.}

if not Assigned(Form_Prueba) then
begin
Application.CreateForm(TForm_Prueba, Form_Prueba);
Form_Prueba.Show;
end else begin
if Form_Prueba.WindowState <> wsNormal then
Form_Prueba.WindowState := wsNormal;
Form_prueba.SetFocus ;
end;

Como esta en modo "Show" se libera el mismo Form desde el evento OnClose con FreeAndNil y funciona bien.


procedure TForm_Prueba.FormClose(Sender: TObject;
var Action: TCloseAction);
begin
FreeAndNil(Form_Prueba);
end;


Pero si deseo agregar un botón "Salir" en mi Form_Prueba al llamar a "Close" me genera un error... supongo que esto es por que FreeAndNil termina los procesos pendientes... y como OnClose es llamado desde otro evento a pesar de hacer el FreeandNil, regresa a terminar el evento OnClick (esto lo probe poniendo Showmessages y si regresa)


procedure TForm_Prueba.btnSalirClick(Sender: TObject);
begin
//Showmessage('');
close;
//Showmessage(''); {Este se msg se muestra a pesar del FreeAndNil}
end;


{*************************************************************************************************** ***************}
Anteriormente tenia en el OnClose el llamado a Release, pero al perecer no libera al Form:


procedure TForm_Prueba.FormClose(Sender: TObject;
var Action: TCloseAction);
begin
release;
end;


por al hacer la siguiente validación, el Assigned alparecer si lo encuentra :


if not Assigned(Form_Prueba) then
...
end;


Esto me confunde, ya que se supone que Release internamente hace su propio Free... y lo ocupaba por que el Release sirve para cuando se quiere liberar el mismo Form que lo invoco a diferencia del Free que es para liberar externamente...

La pregunta general es ¿Como puedo liberar correctamente mi Form desde su evento Onclose y desde un botón "Salir" que invoque a Close; Y que respete la validación: ?


if not Assigned(Form_Prueba) then
begin
Application.CreateForm(TForm_Prueba, Form_Prueba);
Form_Prueba.Show;
end else begin
if Form_Prueba.WindowState <> wsNormal then
Form_Prueba.WindowState := wsNormal;
Form_prueba.SetFocus ;
end;

De antemano gracias y ojala puedan ayudarme!
Buen día saludos.

[rgstuamigo]

Debes hacerlo con FreeAndNil ya que éste hace que el formulario se destruya,libere la memoria ocupada y tu formulario Form_Prueba lo ponga en nulo(nil);
Ten en cuenta que el método Release no destruye al formualrio inmediatamente sino que tan solo manda un mensaje (con la API PostMessage y no con SendMessage), a la cola de Mensajes de Windows informandole que debe ser destruido.
Para entender un poco mas la cuestion puedes leer estos otros hilos.--> 1 (http://www.clubdelphi.com/foros/showthread.php?t=65905&highlight=Release),2 (http://www.clubdelphi.com/foros/showthread.php?t=65148&highlight=Release) etc. aunque mejor seria si chequeas la Ayuda de Delphi.;)
saludos...:)

[look]

Hola que tal, bueno tengo un problema al liberar Form creados en tiempo de ejecución, el siguiente codigo me funciona perfectamente:

Código Delphi [-] (http://www.clubdelphi.com/foros/#) {si el Form no esta creado se crea y se muestra, y si le vuelven a dar click al boton entonces solo lo muestra.} if not Assigned(Form_Prueba) then begin Application.CreateForm(TForm_Prueba, Form_Prueba); Form_Prueba.Show; end else begin if Form_Prueba.WindowState <> wsNormal then Form_Prueba.WindowState := wsNormal; Form_prueba.SetFocus ; end;


Como esta en modo "Show" se libera el mismo Form desde el evento OnClose con FreeAndNil y funciona bien.

Código Delphi [-] (http://www.clubdelphi.com/foros/#)procedure TForm_Prueba.FormClose(Sender: TObject; var Action: TCloseAction); begin FreeAndNil(Form_Prueba); end;


Pero si deseo agregar un botón "Salir" en mi Form_Prueba al llamar a "Close" me genera un error... supongo que esto es por que FreeAndNil termina los procesos pendientes... y como OnClose es llamado desde otro evento a pesar de hacer el FreeandNil, regresa a terminar el evento OnClick (esto lo probe poniendo Showmessages y si regresa)

Código Delphi [-] (http://www.clubdelphi.com/foros/#)procedure TForm_Prueba.btnSalirClick(Sender: TObject); begin //Showmessage(''); close; //Showmessage(''); {Este se msg se muestra a pesar del FreeAndNil} end;


{*************************************************************************************************** ***************}
Anteriormente tenia en el OnClose el llamado a Release, pero al perecer no libera al Form:

Código Delphi [-] (http://www.clubdelphi.com/foros/#)procedure TForm_Prueba.FormClose(Sender: TObject; var Action: TCloseAction); begin release; end;


por al hacer la siguiente validación, el Assigned alparecer si lo encuentra :

Código Delphi [-] (http://www.clubdelphi.com/foros/#) if not Assigned(Form_Prueba) then ... end;


Esto me confunde, ya que se supone que Release internamente hace su propio Free... y lo ocupaba por que el Release sirve para cuando se quiere liberar el mismo Form que lo invoco a diferencia del Free que es para liberar externamente...

La pregunta general es ¿Como puedo liberar correctamente mi Form desde su evento Onclose y desde un botón "Salir" que invoque a Close; Y que respete la validación: ?

Código Delphi [-] (http://www.clubdelphi.com/foros/#) if not Assigned(Form_Prueba) then begin Application.CreateForm(TForm_Prueba, Form_Prueba); Form_Prueba.Show; end else begin if Form_Prueba.WindowState <> wsNormal then Form_Prueba.WindowState := wsNormal; Form_prueba.SetFocus ; end;


De antemano gracias y ojala puedan ayudarme!
Buen día saludos.




if not Assigned(Form_Prueba) then
begin
Form_Prueba:= TForm_Prueba.Create(nil);
Form_Prueba.Show;
end else begin
if Form_Prueba.WindowState <> wsNormal then
Form_Prueba.WindowState := wsNormal;
Form_prueba.SetFocus ;
end;




procedure TForm_Prueba.FormClose(Sender: TObject;
var Action: TCloseAction);
begin
freeandnil(Form_prueba);
end;

[jbautista]

Gracias rgstuamigo si ya me le voy agarrando el hilo, y el detalle con el Release es que probablemente no lo libere al instante...

Ahora tengo dudas mas especificas...

1: FreeAndNil me funciona bien desde el OnClose, cierra y libera el Form desde el boton para cerrar por default de las ventanas de windows.

Pero en algunos casos, cuando pongo un TBotón "Salir" y en su evento OnClick invovo a Close me genera un error.

2. Assigned es la mejor forma de verificar si un Form ya esta creado???

3. Application.CreateForm(TForm_Prueba, Form_Prueba); es la mejor forma para crear el Form???

[jbautista]

Hola look lo que me pusiste lo probe y funciona muy bien cuando el Form se cierra desde el botón Cerrar de las vantanas de Windows


Pero si pongo un botón, y en su evento Onclick llamo al método Close, me genera el siguiente error:

"Abstract Error"

¿¿¿Entonces como hago para que cerrar la ventana desde un botón mio y que se ejecute el evento OnClose pero que ya no regrese al OnClick que lo invoco???

Y por otro lado que diferencia hay de crear mi Form con Application.CreateForm(TForm_Prueba, Form_Prueba) a la que tu me sugeriste Form_Prueba:= TForm_Prueba.Create(nil);???

Gracias.

[rgstuamigo]

....
Ahora tengo dudas mas especificas...

1: FreeAndNil me funciona bien desde el OnClose, cierra y libera el Form desde el boton para cerrar por default de las ventanas de windows.

Pero en algunos casos, cuando pongo un TBotón "Salir" y en su evento OnClick invovo a Close me genera un error.

Te cuento que he probado colocar un boton en el cual llamo al método Close del formualrio y no he tenido problemas.;)
Desde luego para mostrar el formulario lo hago asi (Siguiendo tu ejemplo):
procedure TForm1.Button3Click(Sender: TObject);
begin
if not Assigned(Form2)then
Application.CreateForm(TForm2, Form2);
Form2.WindowState:=wsNormal;
Form2.Show;
end;

En el evento OnClose del formulario (Form2 en mi caso) hago esto:
procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
FreeAndNil(Form2);
end;

Y en un boton que tengo en el formulario 2 (Form2) hago esto:
procedure TForm2.Button1Click(Sender: TObject);
begin
Close;
end;

Y no tengo problemas...;).
Quisas en tu caso tienes algun código mas por ahí , que es el causador del error que mencionas.:rolleyes:;).

2. Assigned es la mejor forma de verificar si un Form ya esta creado???

Bueno...:rolleyes:..si es una forma,en realidad la funcion Assigned lo que hace es Verificar si un puntero o variable es diferente de nulo(nil) algo asi:
if MiVarible<>Nil then// para el caso de una varible
...
ó
if @MiPuntero<>Nil then//para el caso de un puntero
....

De ahi la importancia de utilizar la funcion FreeAndNil.;)

3. Application.CreateForm(TForm_Prueba, Form_Prueba); es la mejor forma para crear el Form???

Es una forma de hacerlo, en realidad delphi en el archivo .DPR asi lo hace, pero tambien puedes hacerlo de esta forma que es equivalente:
procedure TForm1.Button3Click(Sender: TObject);
begin
if not Assigned(Form2)then
Form2:=TForm2.Create(Application);
Form2.WindowState:=wsNormal;
Form2.Show;
end;

Saludos...

[jbautista]

rgstuamigo y look :

Pues algo sigue estando raro con mi codigo, voy a checarlo bien.

Mientras probé de esta manera a ver que opinan:


procedure TForm_principal.btnAbrirClick(Sender: TObject);
var
i:integer;
existe:Boolean;
begin

existe:=False;
{Recorremos los todos Forms Creados}
for i := 0 to (Screen.FormCount - 1) do
{Buscamos si ya existe el Form_Ventana}
if Screen.Forms[i].Name = 'Form_Prueba' then begin
existe:=True;
break;
end;
{Si el Form no existe hay que crear el Form_Ventana}
if not existe then begin
Application.CreateForm(TForm_Prueba, Form_Prueba);
Form_Prueba.Show;
end else begin
if Form_Prueba.WindowState <> wsNormal then
Form_Prueba.WindowState := wsNormal;
Form_prueba.SetFocus ;
end;
end;


Y desde el Form_Prueba puedo cerrar de las siguientes maneras sin ningun error hasta el momento:



procedure TForm_Prueba.BitBtn1Click(Sender: TObject);
begin
close;
end;

procedure TForm_Prueba.FormClose(Sender: TObject;
var Action: TCloseAction);
begin
release;
end;



De esta forma le ven algún detalle que se me escape???

Con la forma que me recomendaron aun sigo checando si el problema es con la validación:

if not Assigned()

o con la llamada Close desde el evento OnClick del Boton.

Muchas gracias de verdad por su tiempo y comentarios.

[rgstuamigo]

Personalmente no lo veo muy óptimo yo prerferiría usar la funcion assigned en ves de recorrer todos formulario y usar el procedimiento FreeAndNil en lugar de Release tal como te hemos mencionado.;)

[roman]

he probado colocar un boton en el cual llamo al método Close del formualrio y no he tenido problemas

Porque has tenido suerte ;)

Yo hice la prueba del compañero y también obtuve un Access Violation. Luego agregué un tercer formulario al proyecto y "funcionó". O sea que, dependiendo de según qué circunstancias, puedes o no tener un problema.

El punto es, que no puedes usar FreeAndNil en el evento OnClose (y en ningún evento del formulario) por la misma razón que no puedes usar Free y debes usar Release en su lugar.

Tú mismo has observado que Release hace un Post del mensaje CM_RELEASE que, a su vez, genera la llamada a Free. Pero, al hacerse vía un Post, se garantiza que el formulario que se destruye ya ha procesado todos los eventos.

Al usar FreeAndNil e invocar el método Close tal como hace el compañero, el problema está en que el formulario se destruye cuando el evento Button1Click aún no termina.

En todo caso, podría funcionar algo como:


procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
Action := caFree;
Form2 := nil;
end;


De todas maneras, a mi en lo particular no me gusta este tipo de métodos. Se supone que una clase no debería hacer referencia a ninguna instancia en particular de ella.

Lo que yo hago en estos casos, es usar el mecanismo de notificaciones entre componentes dado por FreeNotification y Notification.

Cuando creo el formulario, uso


Application.CreateForm(TForm2, Form2);
Form2.FreeNotification(Self);


Esto asegura que Self (el formulario desde donde se abre el segundo formulario) sea notificado cuando Form2 se destruya:


destructor TComponent.Destroy;
begin
Destroying;
if FFreeNotifies <> nil then
begin
while Assigned(FFreeNotifies) and (FFreeNotifies.Count > 0) do
TComponent(FFreeNotifies[FFreeNotifies.Count - 1]).Notification(Self, opRemove);
FreeAndNil(FFreeNotifies);
end;
DestroyComponents;
if FOwner <> nil then FOwner.RemoveComponent(Self);
inherited Destroy;
end;


Entonces, la parte que faltaría, es redefinir el método Notification de TForm1 para, ahí sí, poner en nil la variable:


procedure TForm1.Notification(AComponent: TComponent; Operation: TOperation);
begin
inherited;

if (AComponent = Form2) and (Operation = opRemove) then
Form2 := nil;
end;


// Saludos

[rgstuamigo]

Porque has tenido suerte ;)

Yo hice la prueba del compañero y también obtuve un Access Violation. Luego agregué un tercer formulario al proyecto y "funcionó". O sea que, dependiendo de según qué circunstancias, puedes o no tener un problema.
...

Yo tambien he hecho la prueba nuevamente y he obtenido el error :o(y si que tuve suerte), la verdad creo que es un comportamiento extraño :rolleyes: , ya que si tengo otras controles con algun evento codificado en algunos casos no obtengo dicho error pero en otros si me sale.:o.
De todas formas tambien podriamos solucionarlo(segun mis pruebas) poniendo un componente TBitBtn en lugar del TButton y poner la propiedad Kind=bkClose para que cuando se presione dicho boton el formulario se cierre sin necesidad de codificar nada en su evento OnClick;),desde luego ésto me ha funcionado usando FreeAndNil y no he tenido problemas.:eek:
Saludos...:)

[hach]

Hola,
proba con:

en el evento Close poner solo
Action := caFree;

y en el evento destroy
Form2:=nil;

Saludos

[jbautista]

Hola rgstuamigo y roman que tal, gracias poco a poco me va quedando claro este asunto, no puedo usar definitivamente FreeAndNil desde el mismo Form... suena logico sobre todo por el asunto de invocar al Close de un evento Click de un Botón.

Al usar el Release lo hace bien por que antes de destruir el Form termina todo los procesos pendientes...

Muy bien entonces las conclusiones son las siguientes:

* Entonces para usar la validación Assigned el Form que se valida necesia estar Liberado y con el punturo a NIL, de aqui la importancia del FreeAndNil

* Assigned pordria no funcionar bien con el Release por que antes de liberar al Form manda los mensajes a una cola de espera y poner el puntero a NIL un tiempo mas tarde, por eso al validar el Assigned podria regresar TRUE aunuqe ya se haya liberado el Form.

[jbautista]

Hola Roman de lo que sugeriste tengo unas dudas ya que intente aplicarlo y no pude :P

Esta parte no la tengo poner verdad? o si???




destructor TComponent.Destroy;
begin
Destroying;
if FFreeNotifies <> nil then
begin
while Assigned(FFreeNotifies) and (FFreeNotifies.Count > 0) do
TComponent(FFreeNotifies[FFreeNotifies.Count - 1]).Notification(Self, opRemove);
FreeAndNil(FFreeNotifies);
end;
DestroyComponents;
if FOwner <> nil then FOwner.RemoveComponent(Self);
inherited Destroy;
end;





Y en esta no me reconoce el procedure TForm1.Notification me falta alguna declaración en el USES???


Entonces, la parte que faltaría, es redefinir el método Notification de TForm1 para, ahí sí, poner en nil la variable:


procedure TForm1.Notification(AComponent: TComponent; Operation: TOperation);
begin
inherited;

if (AComponent = Form2) and (Operation = opRemove) then
Form2 := nil;
end;


// Saludos


Gracias! Saludos.

[jbautista]

Hola,
proba con:

en el evento Close poner solo
Action := caFree;

y en el evento destroy
Form2:=nil;

Saludos

Hola hach lo probe y al parecer funciona bien, incluso invocando al Close desde un Boton del mismo Form...

Me respeta correctamente la validación Assigned y no ha provocado ningún error por el momento :P

Con esto no se queda de basura en memoria o algo así???
El Form se libera bien y el puntero se pone a NIL correctamente al parecer...

Alguien opina algo diferente, algún detalle???