Problema con listbox

[mefixxto]

Tengo un listbox al que le cargo datos tipo integer, lo que necesito es hacer un boton que me los ordene a esos datos de menor a mayor y otro boton que me cuente el total de datos que tiene la lista.....

Espero dejarme entender..

Desde ya muchas gracias:)

[luisgutierrezb]

pues tienes la propiedad sorted que te ayuda a ordenar y la propiedad items que dentro de este viene el count para saber la cantidad...

[roman]

Me parece que no va a ser tan fácil como usar Sorted porque el ordenamiento se hace como texto y no como números. Eso implica, por ejemplo, que '10' va antes que '2' a pesar de que 2 es menor que 10.

Se me ocurre usar un TStringList auxiliar y su método CustomSort:


{
Compara dos valores de una lista

La función devuelve:
-1 si List[Index1] es menor que List[Index2]
0 si List[Index1] es igual a List[Index2]
1 si List[Index1] es mayor que List[Index2]

Si alguno de los elementos no es un número entero, la función lanza
una excepción.
}
function CompareNumbers(List: TStringList; Index1, Index2: Integer): Integer;
var
N1, N2: Integer;

begin
if TryStrToInt(List[Index1], N1) and TryStrToInt(List[Index2], N2) then
if N1 < N2 then
Result := -1
else if N1 = N2 then
Result := 0
else
Result := 1
else
raise Exception.Create('La lista contiene valores incorrectos');
end;

procedure TForm1.Button1Click(Sender: TObject);
var
SL: TStringList;

begin
SL := TStringList.Create;
try
// Pasamos los elementos del ListBox a SL
SL.AddStrings(ListBox1.Items);

// Ordenamos usando la función de arriba para comparar elementos
SL.CustomSort(CompareNumbers);

// Regresamos los elementos al ListBox
ListBox1.Items := SL;
finally
SL.Free
end;
end;


// Saludos

[mefixxto]

Me parece que no va a ser tan fácil como usar Sorted porque el ordenamiento se hace como texto y no como números. Eso implica, por ejemplo, que '10' va antes que '2' a pesar de que 2 es menor que 10.

Se me ocurre usar un TStringList auxiliar y su método CustomSort:

Código Delphi [-] (http://www.clubdelphi.com/foros/#){ Compara dos valores de una lista La función devuelve: -1 si List[Index1] es menor que List[Index2] 0 si List[Index1] es igual a List[Index2] 1 si List[Index1] es mayor que List[Index2] Si alguno de los elementos no es un número entero, la función lanza una excepción. } function CompareNumbers(List: TStringList; Index1, Index2: Integer): Integer; var N1, N2: Integer; begin if TryStrToInt(List[Index1], N1) and TryStrToInt(List[Index2], N2) then if N1 < N2 then Result := -1 else if N1 = N2 then Result := 0 else Result := 1 else raise Exception.Create('La lista contiene valores incorrectos'); end; procedure TForm1.Button1Click(Sender: TObject); var SL: TStringList; begin SL := TStringList.Create; try // Pasamos los elementos del ListBox a SL SL.AddStrings(ListBox1.Items); // Ordenamos usando la función de arriba para comparar elementos SL.CustomSort(CompareNumbers); // Regresamos los elementos al ListBox ListBox1.Items := SL; finally SL.Free end; end;


// Saludos

Muchas gracias me sirvo de mucho.-

[mefixxto]

....Y como hago para seleccionar el primer dato de la lista o el ultimo para guardarlo en una variable?

[marcoszorrilla]

procedure TForm1.Button1Click(Sender: TObject);
begin
//Ejemplo mover el primero
Edit1.Text:=ListBox1.Items[0];
end;

Un Saludo.

[marcoszorrilla]

procedure TForm1.Button2Click(Sender: TObject);
begin
//Ejemplo mover el último
Edit1.Text:=ListBox1.Items[Listbox1.Items.count - 1];
end;


Un Saludo.

[dionisiopz]

No comprendo la línea "SL.CustomSort(CompareNumbers);"
Debido a que la función CompareNumbers está declarada como:
"function CompareNumbers(List: TStringList; Index1, Index2: Integer): Integer;" y debería recibir los parámentros declarados, o sea, ¿no hace falta especificar esos parámetros? por ejemplo: "SL.CustomSort(CompareNumbers(List, Index1, Index2));"

Expliquemen por favor. Gracias.

[roman]

Para entender esto, pimero hay que ver la declaración del método CustomSort:


procedure CustomSort(Compare: TStringListSortCompare);


El parámetro es de tipo TStringListSortCompare, que está declarado así:


type
TStringListSortCompare = function(List: TStringList; Index1, Index2: Integer): Integer;


Es decir, el parámetro que se pasa a CustomSort es una función. Esto hay que leerlo bien antes de digerirlo. No se le pasa el valor que devuelve la función (que sería un entero), se le pasa toda la función como parámetro.

Si bien esto puede sonar raro, quizá se te aclare si meditas en para qué se necesita tal cosa.

El origen del problema en este hilo, es que el orden natural de los elementos de un ListBox es textual, no numérico; son dos tipos distintos de ordenamiento:

1, 2, 3, 4, 5, 6 , 7, 8, 9, 10 (numérico)
1, 10, 2, 3, 4, 5, 6, 7, 8, 9 (textual)

En un orden numérico, 2 es menor que 10, pero en un orden textual, 10 es menor que 2 (puesto que al comparar el primer caracter, 1 es menor que 2).

Lo que se ve entonces, es que una lista de elementos siempre será susceptible de ordenarse según diferentes criterios. Un algoritmo de ordenación (tal como QuickSort) puede trabajar con cualquier tipo de elementos (números, cadenas, objetos, etc.) pues lo único que requieren para funcionar es saber cuando un elemento es menor que otro, es decir, sólo necesitan saber cómo comparar dos elementos.

Esto es lo que sucede con CustomSort. A este método, le pasamos una función que compara dos elementos. Internamente, CustomSort tendrá que llevar a cabo muchas comparaciones dos a dos, y tal comparación la hará utilizando la función que le pasamos.

Espero que te haya aclarado algo.

// Saludos