Como hago esto? multi thread?!?!

[MaMu]

Tengo un problema, resulta que yo ejecuto un bucle usando un FOR y un REPEAT que dependiendo de el valor que tome una variable cumple las siguientes ordenes


repeat
for w:=0 to ADOQuery1.RecordCount-1 do
begin
//mis sentencias.....
end;
x:=x-1;
until x=0;


Hasta aca no hay problema alguno y todo se ejecura correctamente.
Pero me pasa en un caso especial, en donde necesito que el Repeat sea infinito, es decir que nunca pare. Tambien puedo hacerlo asignandole una condición que nunca se va a cumplir y listo. Pero mi pregunta es la siguiente:
como hago para detener un ciclo infinito? hacer una suerte de parada de emergencia, porque mientras se ejecuta el ciclo infinito, pierdo el control de la aplicacion, no lo puedo cortar con nada.

Lo que pienso es que debo dejar residente en memoria la parada de emergencia antes de ejecutar el bucle infinito, no se si estoy en lo correcto.

Alguien me puede dar una mano?

Gracias igualmente

[luisgutierrezb]

dentro del bucle puedes usar el application.processmessages y con algun boton ayudado por una variable el break para salir del ciclo si lo quieres cortar

[seoane]

Lo primero es permitir que la "parada" se produzca. Mientras ejecutas un bucle, el resto de la aplicación queda congelada, así que no podríamos indicarle que parase de ninguna manera, ni pulsando un botón, ni una tecla, etc ... así que tenemos que dejar "respirar" a la aplicación. Esto podemos hacerlo de 2 maneras diferentes: usando threads o metiendo dentro del bucle la función "Application.Processmessages".

Yo para un bucle que se tiene que ejecutar "indefinidamente", o por lo menos durante un largo periodo de tiempo, prefiero usar un thread. Este correría de forma paralela al resto de la aplicación. Dentro del thread haría algo como esto:

repeat

until Terminated; // Terminated es una propiedad del objeto TTHread

De esta manera cuando quisiera finalizar el bucle solo tendría que llamar al método "Terminate" del TThread, y el se encargara de poner a TRUE la propiedad Terminated.

Por ejemplo:

MiThread:= TMiThread.Create;
MiThread.FreeOnTerminate:= TRUE;
ShowMessage('Pulsa aceptar para finalizar');
MiThread.Terminate;

Donde TMiThread seria una clase descendiente de TThread.

[MaMu]

Me gusta lo del Thread pero realmente no logro hacerlo, no se donde debo meterlo.


procedure TSecuenciador.dxButton2Click(Sender: TObject);
var MiTHread:TTHread;
w,x:integer;
begin
if CheckBox1.Chequed=True //opcion de infinito o por bucles
then begin
//bucle infinito
end
else begin
x:=StrToInt(SpinEdit1.Text);
//bucle por ciclos
repeat
for w:=0 to ADOQuery1.RecordCount-1 do
begin
//mis sentencias.....
end;
x:=x-1;
until x=0;
end;
end;


Gracias por la ayuda.

[Chris]

dentro de la unidad el thread podrás encontrar el procedimiento execute, en el realizarás las operaciones y calculos que necesites. Es muy recomendable que utilices un thread para esto. ademas, al momento de hacer el llamado MiThread:= TMiThread.Create; tienes un parámetro llamado CreateSuspended, el cual le indica al sistema si el thread se ejecutará de inmediato luego de ser creado o tu lo iniciarás manualmente con el procedimiento Mithread.Resume;

Si alguna de las operaciones que necesitas son manipular los controles o componentes de algún formulario entonces debes de tener cuidado al utilizar el thread porque sino terminarás con un AccessViolation at .... Para evitar esto tiene que utilizar un procedimiento de la clase TThread llamado syncronize y su forma de utilizado es ...


TMiThread.ActualizarControles;
begin
form1.label1.caption := 'x porciendo del proceso completado';
end;

{para llamar al procedimiento anterior desde el procedimiento execute lo haces de la siguiente manera con syncronize}
TMiThread.Execute;
begin
...

Syncronize(ActualizarControles);

...

end;


De esta forma te evitaras los fastidios AccessViolatios.

Esto es lo que te puedo decir por ahora, pero siempre ten cuidado con la sincronización porque puedes terminar con un grave bug dentro de tu aplicación.

[MaMu]

dentro de la unidad el thread podrás encontrar el procedimiento exceute, en el realizarás las operaciones y calculos que necesites. Es muy recomendable que utilizes un thread para esto.

Pero no esta el procedimiento execute. Lo unico que tengo es lo que me aparece cuando escribo MiThread. .......listado....... pero execute no esta.

Saludos

[seoane]

Bueno, aqui te dejo un ejemplo muy simple de como usar un thread.


unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;

type
TForm1 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

// Aquí declaramos una clase nueva descendiente TThread
TMiThread = class(TThread)
protected
procedure Execute; override;
public
constructor Create;
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

// Este es el evento OnClick de un boton que coloque en el formulario
procedure TForm1.Button1Click(Sender: TObject);
var
MiThread: TMiThread;
begin
// Creamos el thread
MiThread:= TMiThread.Create;
// Mostramos un mensaje
ShowMessage('Pulsa aceptar para terminar');
// Cuando el mensaje se cierra, terminamos el thread
Mithread.Terminate;
end;

{ TMiThread }

constructor TMiThread.Create;
begin
inherited Create(FALSE);
// Aqui le indicamos que cuando la ejecucion del thread termine
// debe liberar el objeto TMithread
FreeOnTerminate:= TRUE;
end;

// Este procedimiento se llama justo después de crear el objeto, y se
// ejecuta de forma paralela al resto de la aplicación.
procedure TMiThread.Execute;
begin
repeat
Windows.Beep(500,100);
// Siempre que tengamos un bucle de este tipo, es conveniente usar algún
// retardo para no abusar de la CPU. A lo mejor en tu código no es necesario.
Sleep(1000);
until Terminated;
end;

end.


En el ejemplo anterior, hacemos sonar un pitido a intervalos de un segundo. Como ves, el bucle se tiene que insertar en el método "Execute" del TThread.

[MaMu]

Gracias muchachos, al final logré solucionar el tema. Lo que encuentro interesante es la forma en que pueden dividirse las instrucciones. yo que hago programas para controlar hardware externo, me viene como anillo al dedo.

Saludos