Actualización aplicaciones

[Jose Manuel]

Hola, tengo hecha una aplicación en Delphi 6, y quisiera incluir una opción en el programa, para que al pulsar en ella se conectase a Internet y comprobase, si en mi pagina WEB hay una versión más moderna de dicho programa.

Si además de informar, diera la opción de actualizar el programa, mucho mejor.

No sé como se podría hacer esto, así es que agradecería cualquier ayuda sobre este tema.

Un saludo.
Jose Manuel García

[Neftali [Germán.Estévez]]

La forma más común es almacenando en la página WEB el programa y un fichero TXT (por ejemplo) con los datos de la versión.

(1) Desde tu programa te descargas el fichero TXT que podría ser así:
----------------------------------
version=1.1.0.1234
----------------------------------
(2) Comparas la versión de tu programa con la del fichero.
(3) Si la de tu programa es menor, debes actualizar.
(4a) Descargas el programa y lo guardas en un directorio temporal.
(4b) Cierras tu programa, pero antes lanzas una segunda aplicación (UPDATER) que se encarge de:
(A) Copiar el fichero descargado al lugar donde está tu aplicación
(B) Volver a ejecutar tu aplicación.

[Neftali [Germán.Estévez]]

También hay componentes por internet que te hacen más o menos estos pasos. Tú mismo...

[Jose Manuel]

Hola, voy a ver hasta donde llego con la información que me has dado ..., aunque es posible que vuelva a preguntar alguna cosa sobre este tema.

Un saludo, y muchas gracias

Jose Manuel.

[seoane]

No es exactamente lo que tu buscas, pero puede que saques alguna idea interesante de aquí:

http://www.clubdelphi.com/foros/showthread.php?t=32550

[comba]

Quiero a finar un poco más. Eso que dice neftali ya lo tengo y funciona de maravilla.

Pero me gustaria si es posible hacerlo todo en un fichero. No tener por un lado la aplicacion y por el otro el update.

¿Se podría generar un fichero en dos para reemplazará el exe actual por el nuevo?¿Y como abriríamos el programa automáticamente?

Me refiero a que abres tu programa y te dice que hay una nueva versión, te la descargas la reemplazas y quieres que se vuelve abrir la aplicación de nuevo.

Un saludo y gracias.

[Neftali [Germán.Estévez]]

...Pero me gustaria si es posible hacerlo todo en un fichero. No tener por un lado la aplicacion y por el otro el update.

El problemqa es que un fichero no puede reemplazarse a sí mismo, cerrarse y luego abrirse.

...¿Se podría generar un fichero en dos para reemplazará el exe actual por el nuevo?

Eso no lo he entendido.

[comba]

Quizás no me explique muy bien. Así que lo siento.
Lo que quise decir es lo siguiente.

Yo tengo dos aplicaciones,una aplicación que es el programa y la otra para actualizar la aplicación(updater).
Cuando entro en mi aplicación y hay una nueva versión, cierro la aplicación y abro el updater.
Entonces descargo,descomprimo y renombro la aplicación antigua y copia la nueva aplicación. y antes de cerrar el updater abró la nueva aplicación.

¿Eso sería posible hacerlo todo en una aplicación?.

Mi idea hacer todo esto en una aplicación pero antes de reemplazar el archivo que estoy ejecutando, hacer algo que lo reemplace y abrá la aplicación. Y he pensado si eso sería posible con una archivo de ms-dos.



Pero de todas formas gracias si tienes la respuesta, ya que creo que tengo la solución.

Un saludo.

[Neftali [Germán.Estévez]]

Quizás no me explique muy bien.

Sí te has explicado bien, pero la respuesta sigue siendo la misma. No puede hacerse con una única aplicación, porque una aplicación no puede reemplazarse a sí misma (mientras se está ejecutando) y no puede cerrarse y volverse a abrir ella sóla.

...pero antes de reemplazar el archivo que estoy ejecutando, hacer algo que lo reemplace y abrá la aplicación...

Esta frase no la entiendo... ;)

...he pensado si eso sería posible con una archivo de ms-dos.

Llámalo UPDATER o aplicación de MS-DOS, pero necesitas una segunda aplicación que como mínimo:
(1) Reemplace la aplicación principal (que no puede estar ejecutándose)
(2) Que ejecute la aplicación principal (la versión nueva).

[seoane]

Aunque pienso que es complicarse demasiado, aquí te dejo una manera de hacerlo usando un archivo bat. Cuando quieras actualizarte, llama a la siguiente función pasándole la ruta del nuevo ejecutable, y cierra tu programa. El archivo bat se encargara de actualizar y volver a ejecutar tu aplicación.


procedure Actualizate(Nuevo: string);
var
Actual: String;
Buffer: array[0..MAX_PATH] of Char;
begin
if GetShortPathName(PChar(ParamStr(0)),@Buffer, Sizeof(Buffer) -1) = 0 then
Exit;
Actual:= String(PChar(@Buffer));
if GetShortPathName(PChar(Nuevo),@Buffer, Sizeof(Buffer) -1) = 0 then
Exit;
Nuevo:= String(PChar(@Buffer));
with TStringList.Create do
try
Add(':BUCLE');
Add('Del ' + Actual);
Add('if %ERRORLEVEL% NEQ 0 goto BUCLE');
Add('Copy ' + Nuevo + ' ' + Actual);
Add('Start ' + Actual);
SaveToFile(ChangeFileExt(ParamStr(0),'.bat'));
ShellExecute(0,nil,PChar(ChangeFileExt(ParamStr(0),'.bat')),nil,nil,SW_SHOW);
finally
Free;
end;
end;

// Ejemplo de uso
Actualizate('c:\Windows\Temp\nuevo.exe');
Halt; // Lo apropiado seria usar close, o algo similar

[Jose Manuel]

Estoy siguiendo los puntos que me dices

(1) Desde tu programa te descargas el fichero TXT que podría ser así:
----------------------------------
version=1.1.0.1234
----------------------------------
(2) Comparas la versión de tu programa con la del fichero.
(3) Si la de tu programa es menor, debes actualizar.
(4a) Descargas el programa y lo guardas en un directorio temporal.
(4b) Cierras tu programa, pero antes lanzas una segunda aplicación (UPDATER) que se encarge de:
(A) Copiar el fichero descargado al lugar donde está tu aplicación
(B) Volver a ejecutar tu aplicación.

y en el primer paso, me gustaría no descargar el programa, sino leer el contenido de un fichero de texto y pasarlo una variable. ¿Como se hace esto utilizando delphi6? o en caso de que no se pueda hacer facilmente, como se podría descarga un fichero de texto de forma que no pregunte al usuario si lo quiere guardar o abrir.

Un saludo
Jose Manuel García

[Neftali [Germán.Estévez]]

...y en el primer paso, me gustaría no descargar el programa, sino leer el contenido de un fichero de texto y pasarlo una variable.

Es que en el primer paso no dice que descargues el programa, sino descargar el fichero de texto para leerlo.

...como se podría descarga un fichero de texto de forma que no pregunte al usuario si lo quiere guardar o abrir.

Pon un botón en un formulario y añade este código:


procedure TForm1.Button1Click(Sender: TObject);
var
b:Boolean;
TS:TStrings;
Str:String;

//----------------------------------------------------------------------------
function DownloadFile(Source, Dest: string): Boolean;
begin
// proteccion
try
Source := AnsiReplaceStr(Source, '/', '\');
Result := UrlDownloadToFile(nil, PChar(Source), PChar(Dest), 0, nil) = 0;
except
Result := False;
end;
end;
//----------------------------------------------------------------------------
begin

// descargar
b := DownloadFile('http://neftali.clubdelphi.com/temp/test_vrs.txt',
'c:\temp\test_vrs.txt');
// correcto?
if (b) then begin
// Crear TStrings
TS := TStringList.Create();
// Coger la version
TS.LoadFromFile('c:\temp\test_vrs.txt');
Str := TS[1];
// Avisar
MessageDlg('Versión en el Servidor: ' + Str, mtInformation, [mbOK], 0);
// Liberar
TS.Free;
end;
end;


Tendrás que añadir al uses las units StrUtils y urlMon.
Este código descarga el fichero TXT (del que hablamos más arriba) y lee la línea 1 (que contiene la versión).

[Jose Manuel]

Muchisimas gracias, me ha funcionado correctamente. He conseguido comparar la versión del PC con la que hay en mi Web y que salga un aviso en la pantalla. En principio eso era lo que queria, dar al usuario la opción de conocer nuevas versiones.

No sé, es posible que intente continuar para ver como se podría actualizar el ejecutable, aunque de momento no lo ponga en el programa, pero estaría bien conocer que problemas tendría....

Muchas gracias por la información, me ha sido de gran utilidad.

Un saludo para todos, especialmente para los que han respondido.
Jose Manuel.

[Neftali [Germán.Estévez]]

No sé, es posible que intente continuar para ver como se podría actualizar el ejecutable, aunque de momento no lo ponga en el programa, pero estaría bien conocer que problemas tendría....

Bueno, no es difícil utilizando los componentes de la Indy.
En mi página (http://neftali.clubdelphi.com/delphi_ejemplos.html#Descargar_un_fichero_y_copiarlo_en_local) acabo de subir un ejemplo sencillo para descargar un fichero y copiarlo en un directorio local.

[Jose Manuel]

Hola, al final con vuestra ayuda he conseguido, poner en un Procedure el código necesario para "Consultar si hay nueva versión, descargala a un directorio y descomprimir el ZIP sustituyendo el ejecutable".

Os pongo el código que he utilizado, un poco largo tal vez para poner en el foro, pero no sé... tal vez le sea útil a alguien.

Para utilizarlo, solo hay que pegar el código en nuestra aplicación, y cambiar las variables que figuran en color rojo.
Un saludo a todos
Jose Manuel.


// Este procedimiento se puede pegar a nuestras aplicaciones, y sirve para actualizar
// una aplicación informática, primero comprueba las versiones y si son distintas
// baja de la Web la actualización, descomprimiendo el contenido en la carpeta del *.exe.
// Para que funcione este procedimiento debemos:
// 1. Tener un pagina WEB
// 2. Subir la actualización en formato ZIP
// 3. Subir un fichero en formato *.TXT con 2 lineas (1 con la versión y otra con la fecha)


procedure TfMenu.chk_nuevas_versionesClick(Sender: TObject);
// poner en uses: WinInet, Registry, WinSock, StrUtils, urlMon;
var
vInst:string; // almacena la versión instalada en el PC
dir_exe:String; // carpeta desde la que se ejecuta el *.exe
dir_tmp:String; // carpeta temporal, utilizada para descargar los ficheros
fic_web_txt:String;// ruta para descargar fichero txt con la versión
fic_pc_txt:String; // ruta en el pc donde se ha descargado fichero txt con la versión
fic_web_zip:String;// ruta para descargar fichero ZIP con la actualización
fic_pc_zip:String; // ruta en el pc donde se ha descargado fichero ZIP con la actualización
params:string; // parametros utilizados para decir a WINZIP como descargar el fichero
nom_apli:String; // nombre de la aplicación
msg:string; // variable para almacenar los mensajes
b:Boolean;
TS:TStrings; // TStringList creada para leer el fichero
Str:String; // versión instalada en el Servidor
fec:String; // fecha de la nueva versión
titulo:String;
//----------------------------------------------------------------------------
function DownloadFile(Source, Dest: string): Boolean;// función para descargar
begin
try
Source := AnsiReplaceStr(Source, '/', '\');
Result := UrlDownloadToFile(nil, PChar(Source), PChar(Dest), 0, nil) = 0;
except
Result := False;
end;
end;
//----------------------------------------------------------------------------
function GetAppVersion:string; // función para obtener la versión instalada
var
Size, Size2: DWord;
Pt, Pt2: Pointer;
begin
Size := GetFileVersionInfoSize(PChar (ParamStr (0)), Size2);
if Size > 0 then
begin
GetMem (Pt, Size);
try
GetFileVersionInfo (PChar (ParamStr (0)), 0, Size, Pt);
VerQueryValue (Pt, '\', Pt2, Size2);
with TVSFixedFileInfo (Pt2^) do
begin
Result:= IntToStr (HiWord (dwFileVersionMS)) + '.' +
IntToStr (LoWord (dwFileVersionMS)) + '.' +
IntToStr (HiWord (dwFileVersionLS)) + '.' +
IntToStr (LoWord (dwFileVersionLS));
end;
finally
FreeMem (Pt);
end;
end;
end;
//----------------------------------------------------------------------------
begin


// ini: Solo se deben modificar estas variables para adaptarlas a nuestra aplicación
nom_apli := 'VISOR';
dir_tmp := 'c:\temp';
fic_web_txt:= 'http://www.paginaweb.es/ficheros/version_visor.txt';
fic_pc_txt := 'c:\temp\version_visor.txt';
fic_web_zip:= 'http://www.paginaweb.es/ficheros/visor_act.zip';
fic_pc_zip := 'c:\temp\visor_act.zip';
params := '-e -o '+fic_pc_zip; // -e = extract -o = sobreescribir
// fin:

// notas sobre parametros pasados al Winzip
// -a add/replace files
// -e extract /descomprimir ficheros
// -f actualiza ficheros en destino
// -t test archive
// -o no pregunta si queremos sobreecribir el fichero

vInst:= GetAppVersion; // obtener la versión instalada
dir_exe:=ExtractFilePath(paramstr(0)); // el directorio del ejecutable a actualizar

If not DirectoryExists(dir_tmp) then
if not createdir(dir_tmp) then
begin
raise exception.create('Proceso cancelado al no poder creárse la carpeta '+dir_tmp);
exit;
end;
// descargamos el fichero de texto con información de la última versión
b := DownloadFile(fic_web_txt,fic_pc_txt);

if (b) then begin
TS := TStringList.Create();
TS.LoadFromFile(fic_pc_txt);
Str := TS[0];// 1º linea del fichero, poner la versión del programa, ejem. 6.1.0.2
fec := TS[1];// 2º linea del fichero, poner la fecha de la versión, ejem. 14-11-2006
TS.Free;
DeleteFile(fic_pc_txt);
msg:= 'Versión en este ordenador: '+ vInst+#13+
'Versión en el Servidor____: ' + Str+' de '+fec;

if vInst<>Str then // si las versiones son distintas
begin
msg:=msg+#13+#13+'Quieres descargar la nueva versión';

titulo:='Descargar actualización '+nom_apli;
if application.MessageBox (pchar(msg),
PCHAR(titulo),
(MB_YESNO + MB_DEFBUTTON2 + MB_ICONQUESTION)) <> IDYES then exit;

DownloadFile(fic_web_zip,fic_pc_zip);

msg:= 'Ha descargado la nueva actualización, '+#13+
'al directorio '+dir_tmp+', para instalarla'+#13+
'en su ordenador no debe haber ningún'+#13+
'usuario conectado a la aplicación.'+#13+#13+
'Quiere instalar la nueva versión';

titulo:='Actualizar '+nom_apli;
if application.MessageBox (pchar(msg),
PCHAR(titulo),
(MB_YESNO + MB_DEFBUTTON2 + MB_ICONQUESTION)) <> IDYES then exit;
begin
ShellExecute(Handle, 'Open', 'WinZip32.exe', PCHAR(params), PCHAR(dir_exe), SW_NORMAL);
Application.Terminate;
end;
end
else
Application.MessageBox((pChar(msg+#13+#13+'NO HAY NUEVAS ACTUALIZACIONES')) , 'Comprobación versiones', MB_ICONEXCLAMATION) ;
end
else
ShowMessage('Esta comprobación solo se puede hacer'+#13+
'en ordenadores conectados a Internet.'+#13+
'Su equipo no tiene esta conexión'+#13+
'- Proceso Cancelado -');
end;